Macro para ocultar/exibir planilha

[Seiki2000]

Pessoal estou precisando de uma macro para ocultar e exibir planilha.
Alguém poderia me ajudar?

[schiavinatto]

Coletânea de Macros sobre Planilhas:

'================================================|
    Sub PlanilhaAtivaOcultar
    'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
    Dim oPlan As Object
    oPlan = ThisComponent.getCurrentController.getActiveSheet()
    oPlan.isVisible = False
    End Sub

.

'================================================|
    Sub PlanilhaOcultar
    'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
    Dim oPlan As Object
    oPlan = ThisComponent.getSheets.getByName("Planilha1")    'Nome da Planilha
    oPlan.isVisible = False
    End Sub

.

 '================================================|
   Sub PlanilhaOcultarMostrar 
    'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
    Dim oPlan As Object
    oPlan = ThisComponent.getSheets.getByName("Planilha1")    'Nome da Planilha
    oPlan.isVisible = Not oPlan.isVisible
    End Sub

.

'================================================|
    Sub PlanilhaMostrar
    'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
    Dim oPlan As Object
    oPlan = ThisComponent.getSheets.getByName("Planilha1")    'Nome da Planilha
    oPlan.isVisible = True
    End Sub

.

    '================================================|   
     Sub PlanilhaOcultarTodasExetoAtiva
     'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
        Dim oPlanAtiva As Object
        Dim oPlans As Object
        Dim co1 As Long
        oPlanAtiva = ThisComponent.getCurrentController.getActiveSheet()
        oPlans = ThisComponent.getSheets()
        	For co1 = 0 To oPlans.getCount() - 1
        	If oPlans.getByIndex(co1).getName <> oPlanAtiva.getName() Then
        	oPlans.getByIndex(co1).isVisible = False
        	End If
        	Next
        End Sub

.

'================================================|
Sub PlanilhaExcluir
'================================================|
thisComponent.getSheets.RemoveByName("Planilha5")   'Nome da Planilha
end Sub

.

'================================================|
Sub PlanilhaNova
'================================================|
thisComponent.getSheets.InsertnewByName( "Planilha1", 0)   'Nome da Planilha, Posição
end Sub

.

 '================================================|
Sub PlanilhaRenomear
'by: Macros para o OpenOffice.org - Calc (Tarcízio da Rocha)
 '================================================|
Dim oDoc as Object
Dim oSheet as Object
oSheet = thisComponent.sheets ("Nome Atual") 'Nome daPlanilha Atual
oSheet.name = "Nome Novo"   'Nome da Planilha Nova
End Sub

.

Rem Attribute VBA_ModuleType=VBADocumentModule
Option VBASupport 1
Option Explicit
'================================================|
Sub PlanilhasOrdenarPelosNomes()
' Código para ordenação das planilhas de um arquivo
' de trabalho com base nos seus nomes.
'================================================|
Dim k           As Integer
Dim i           As Integer
Dim Tipo        As Integer
Dim Mensagem    As String
'Exibir caixa de mensagem para que o usuário possa selecionar o tipo de ordenação desejada
Mensagem = "Pressione Sim para ordenação crescente" & vbLf & _
"e Não para ordenação decrescente"
Tipo = MsgBox(Mensagem, vbYesNo + vbApplicationModal, _
"Ordenar planilhas")
Select Case Tipo
Case vbYes
    'Opção de ordenação crescente
    For k = 1 To ThisWorkbook.Sheets.Count
        For i = 1 To ThisWorkbook.Sheets.Count - 1
            If Sheets(i).Name > Sheets(i + 1).Name Then
            Sheets(i + 1).Move Before:=Sheets(i)
            End If
        Next i
    Next k
Case vbNo
'Opção de ordenação decrescente
    For k = 1 To ThisWorkbook.Sheets.Count
        For i = 1 To ThisWorkbook.Sheets.Count - 1
            If Sheets(i).Name < Sheets(i + 1).Name Then
            Sheets(i + 1).Move Before:=Sheets(i)
            End If
        Next i
    Next k
End Select
End Sub

.

'================================================|
Sub PlanilhaMover
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlan As Object
	oPlan = ThisComponent.getSheets()
	oPlan.moveByName( "Planilha3", 0 )    'Planilha a Mover , Posição
End Sub

.

'================================================|
Sub PlanilhaMoverFinal
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlan As Object
	oPlan = ThisComponent.getSheets()
	oPlan.moveByName( "Planilha1", oPlan.getCount() )     'Planilha a Mover para o Final
End Sub

.

'================================================|
Sub PlanilhaCopiar
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlan As Object
	oPlan = ThisComponent.getSheets()
	oPlan.copyByName( "Planilha2", "Planilha2_Nova", 0 )    ‘PlanilhaCopiar, PlanilhaNovaCopiada, Posição
End Sub

.

'================================================|
Sub PlanilhaCopiarFinal
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlan As Object
	oPlan = ThisComponent.getSheets()
	oPlan.copyByName( "Planilha3", "Planilha3_Nova", oPlan.getCount() )    ‘PlanilhaCopiar, PlanilhaNovaCopiada
End Sub

.

'================================================|
Sub PlanilhaProteger
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlanAtiva As Object
oPlanAtiva = ThisComponent.getCurrentController().getActiveSheet()
oPlanAtiva.Protect( "senha" )       'senha para proteger
End Sub

.

'================================================|
Sub PlanilhaDesproteger
'by Aprendiendo OOo Basic - Mauricio Baeza Servín
'================================================|
Dim oPlanAtiva As Object
	oPlanAtiva = ThisComponent.getCurrentController().getActiveSheet()
	If oPlanAtiva.isProtected Then
		MsgBox "Planilha esta protegida"
 		oPlanAtiva.unProtect( "senha" )     'senha para desproteger
	  	If oPlanAtiva.isProtected Then
			MsgBox "A Senha não esta correta"
		Else
			MsgBox "Planilha desprotegida"
		End If
	Else
		MsgBox "Planilha não eata protegida"
	End If
End Sub

.

---

Caso a resposta atendeu sua necessidade, por gentileza, click na bolinha a esquerda da resposta, para finalizar a pergunta.

[Seiki2000]

Nossa, Gilberto !
Muito obrigado era tudo que eu estava precisando.

[schiavinatto]

Ok, é bom saber que foi útil.