Conteggio e selezione valore celle da sinistra a destra

Atreyus · December 31, 2019, 10:23am

Salve a tutti, dopo aver risolto grazie a questa formula:=SE(O(J2>=3;J2<=-3);J2;K2)

Ho bisogno che continui a controllare numeri nella cella successiva sulla stessa riga finché ci sono numeri e non che si fermi, in questo caso a k2.

Se trovasse prima 3 e poi 4 ad esempio vale il primo che ha raggiunto il minimo necessario e cioè 3; Se trova dei doppi, vale il primo trovato; se valori minori, semplicemente non segna nulla, ma questo credo lo faccia già.
Scusate ma sono ignorante in materia di codice.

Grazie mille in anticipo!

gioh66 · December 31, 2019, 8:00pm

Ciao, allega un esempio con il risultato che vorresti.

Atreyus · January 1, 2020, 10:22am

Scusa ma non so perché non mi è arrivata la notifica di questo commento…provvedo subito! Buon anno!

Atreyus · January 1, 2020, 11:28am

Ecco, tenendo conto della formula sopra che prende i valori 3 e -3 e ovviamente tralasciando che analizzi non J e K ma in questo caso da A in poi, il risultato è nella colonna M.

Come vedete nelle righe 7 e 13 non vengono raggiunti i valori 3 e -3 e di conseguenza non viene riportato alcun valore.

Per comodità ho evidenziato le celle da dove prende il risultato.

Prova.ods

Grazie mille!

gioh66 · January 1, 2020, 7:44pm

Per cominciare ti auguro buon anno. Poi sperando di aver compreso bene le casistiche, in M2 da tirare in basso prova

=SE(E(VAL.NUMERO(CONFRONTA(3;A2:K2;0));VAL.NUMERO(CONFRONTA(-3;A2:K2;0)));MIN(A2:K2);SE(VAL.NUMERO(CONFRONTA(-3;A2:K2;0));-3;SE(VAL.NUMERO(CONFRONTA(3;A2:K2;0));3;SE(E(CONTA.SE(A2:K2;"<"&-3)=0;CONTA.SE(A2:K2;">"&3)>0);MAX(A2:K2);SE(CONTA.SE(A2:K2;"<"&-3)>0;MIN(A2:K2);SE(CONTA.SE(A2:K2;">"&3)>0;MAX(A2:K2);""))))))

Ti allego il file dove nella colonna N ci sono i risultati della formula.3_-3.ods

Atreyus · January 1, 2020, 10:41pm

Sto impazzendo…ho applicato la formula alla riga reale sul mio foglio e mi da un risultato errato…

allego lo stesso foglio ma con la prima riga modificata con i dati del mio foglio, che invece di 5 da -6 e non riesco proprio a capire perchè…

non so come allegare il foglio nel commento quindi lo modifico nella risposta qui sotto.

Atreyus · January 1, 2020, 10:43pm

che adesso è andata su scusate ma sono le prime volte che uso questo forum e devo ancora ambientarmi con le funzioni…

gioh66 · January 2, 2020, 1:05pm

Eh purtroppo questo forum ha dei limiti (a mio parere)
Tornando al tuo problema ho aggiornato la formula per soddisfare anche l’ultimo requisito

=SE(E(CONTA.SE(A2:K2;"<"&-3)>0;CONTA.SE(A2:K2;">"&3)>0;NON(VAL.NUMERO(CONFRONTA(-3;A2:K2;0))));MAX(A2:K2);SE(E(VAL.NUMERO(CONFRONTA(3;A2:K2;0));VAL.NUMERO(CONFRONTA(-3;A2:K2;0)));MIN(A2:K2);SE(VAL.NUMERO(CONFRONTA(-3;A2:K2;0));-3;SE(VAL.NUMERO(CONFRONTA(3;A2:K2;0));3;SE(E(CONTA.SE(A2:K2;"<"&-3)=0;CONTA.SE(A2:K2;">"&3)>0);MAX(A2:K2);SE(CONTA.SE(A2:K2;"<"&-3)>0;MIN(A2:K2);SE(CONTA.SE(A2:K2;">"&3)>0;MAX(A2:K2);"")))))))

Nel file allegato l’ultima condizione che hai posto è alla riga 16.
Prova se funziona, altrimenti metti un file con indicate tutte le condizioni. Ricostruirle solo guardando l’esempio postato non è semplice.

Atreyus · January 2, 2020, 1:50pm

Innanzitutto grazie davvero moltissimo per l’interessamento,veramente gentilissimo.

Purtroppo come gli metto unaltra riga sbaglia…

a questo punto ti allego i dati completi e reali cosi magari riesci, perdonami per non averlo fatto fin da subito ma, essendo solo valori negativi e non, quindi 2 cose e basta, credevo funzionasse su tutti i numeri a prescindere dal loro valore, e spero sia coì anzi se non lo è non riesco praticamente ad utilizzarlo, perche i numeri sono sempre diversi col passare del tempo…

Ri-modifico il file nella prima risposta.

Grazie ancora moltissimo, davvero.

Atreyus · January 2, 2020, 1:54pm

Per le condizioni è semplice, da sinistra verso destra il primo valore che è = o maggiore di 3 e = o minore di -3 viene segnato.

gioh66 · January 2, 2020, 2:58pm

Ok, allora se le condizioni sono queste prova così: in AJ (o dove credi) metti la seguente formula matriciale.

=SE.ERRORE(INDICE(A2:AH2;PICCOLO(SE((A2:AH2<=-3)+(A2:AH2>=3);RIF.COLONNA($A$1:$AH$1));1));"")

Per inserire la formula apri la cella in modalità di modifica, con doppio click o premendo il tasto F2, copia e incolla la formula e confermala con la combinazione di tasti ctrl+maiuscolo+ invio e non col solo invio.
Ti do il link del nuovo file, dove nella colonna in giallo c’è il risultato della formula.

Atreyus · January 2, 2020, 4:23pm

gioh66 sei un mito!!! Funziona!!

Guarda non so come ringraziarti mi hai davvero cambiato la giornata!

Ti chiedo solo per conferma se è normale che debba per forza partire dalla colonna A, in quanto io ho sempre dalla colonna A alla K altri dati e questi numeri mi partono sempre dalla colonna L in poi.
Dovro sempre spostarli alla A o ce modo di avere i dati corretti anche dalla L in poi?
Perchè, per ora, mi da dei risultati errati se parto dalla L…

Comunque ripeto mi hai gia cambiato la giornata se è troppo complicato mi adatto!!!

gioh66 · January 2, 2020, 8:33pm

Se i tuoi dati partono dalla colonna L basta cambiare i riferimenti. Supponendo che i tuoi dati vadano dalla colonna L alla AS la formula diventa così

=SE.ERRORE(INDICE(L2:AS2;PICCOLO(SE((L2:AS2<=-3)+(L2:AS2>=3);RIF.COLONNA($L$1:$AS$1)-RIF.COLONNA($K$1);1));"")

Se ti chiedi perchè ho fatto quella sottrazione dei RIF.COLONNA() è bene che tu sappia che la formula RIF.COLONNA($A$1:$AH$1) serve a creare una matrice 1, 2, 3, 4, ecc…che serve ad indicare in quale posizione si trova il primo criterio che corrisponde alle condizioni <=-3 o >=3; questo se parti dalla colonna A.
Dovendo tu iniziare la formula dalla colonna L, che è la colonna 12, per far partire il conteggio da 1 gli sottraggo RIF.COLONNA($K$1) che corrisponde a 11.

Per chiarezza ti do il link del file dove ho inserito colonne vuote fino alla L
https://www.dropbox.com/s/plzk4ezkyu4dby7/3_-3%20(bis-3).ods?dl=0

Atreyus · January 3, 2020, 2:45pm

Dopo tutte le prove possibili e immaginabili sono qui a dirti gioh66 che se passi da Parma hai una cena pagata!!! Davvero non so come ringraziarti, grazie davvero moltissimo…

gioh66 · January 3, 2020, 3:32pm

Grazie a te del riscontro!
Ps.: anche se mi pare tu abbia già risolto, mi sono dimenticato di dirti che le formule matriciali, dopo essere state inserite nella prima cella come ti ho detto sopra, per estenderle alle celle sottostanti, và copiata e incollata la prima cella in basso.