Abrir o Calc em tela cheia ocultar barras, guias e ferramentas

[Dambia]

Boa tarde,

Gostaria de algumaforma para abrir uma planilha específica em tela cheia, sem as barras e guias, como se fosse um sistema para o escritório que trabalho. No caso, uma vez configurada a planilha abriria dessa forma nas outras máquinas também.

Já havia trabalhado em planilhas do tipo no excel, gostaria de saber se há como fazer algo parecido no Libreoffice.
Deixo abaixo o link referência:

Abrir o Excel em tela cheia ocultar barras, guias e ferramentas

[schiavinatto]

As macro são estas:

Lembrando, toda navegação entre planilhas terá que ser por botões/figuras geométrica/imagens com macros

'================================================|
Sub TelaInteiraLigar
	'Para abrir TELA INTEIRA na abertura do arquivo
	'Ferramentas / Personalizar / Eventos
	'Ao abrir documento
	'ligar a MACRO ok.
'================================================|
Dim oSheet As Object
Dim oController As Object
oSheet = ThisComponent.Sheets.getByName("Planilha1")  '<== Planilha a Visualizar Inicialmente.
oController = ThisComponent.CurrentController
With oController
	.setActiveSheet(oSheet)
	.ColumnRowHeaders = False
	.SheetTabs = False
	.Frame.LayoutManager.HideCurrentUI = True
	.Frame.Title = "Titulo do Aplicativo"   '<== Titulo do Aplicativo, mostra na Barra superior.
end With
end sub

.

'================================================|
Sub TelaInteiraDesligar
'================================================|
Dim oController As Object
oController = ThisComponent.CurrentController
With oController
	.ColumnRowHeaders = True
	.SheetTabs = True
	.Frame.LayoutManager.HideCurrentUI = False
	.Frame.ComponentWindow.SetFocus() '<<<< Devolver o foco a janela <<<<'
End With
End Sub

.

A navegação é simples: exemplo ir para a planilha 1 em A1

Sub Planilha1
   Call IrPara "Planilha1.A1"
End Sub

Usando esta SubMacro:

'================================================|
sub IrPara (xlocal as string)
'exemplo uso: IrPara "Planilha.A1" ou "Planila1.A1:B3" ou "NomeArea"
'================================================|
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "ToPoint"
args1(0).Value = xlocal
dispatcher.executeDispatch(document, ".uno:GoToCell", "", 0, args1())
end sub

Veja um arquivo como modelo aqui: https://wiki.documentfoundation.org/images/3/39/ModeloArquivoCalc1.ods

E um como aplicativo: https://wiki.documentfoundation.org/images/c/c2/Agendamento_de_Consultas.ods

do Escritório Aberto, https://wiki.documentfoundation.org/PT-BR/Projetos/EA

---

Caso a resposta atendeu sua necessidade, por gentileza, click na bolinha a esquerda da resposta, para finalizar a pergunta.

[Dambia]

Boa tarde,

A planilha está funcionando perfeitamente em minha máquina. Na dos meus colegas aparece o seguinte erro ao abrir:

 Ocorreu um erro de Scripting Framework durante a execução do script Basic vnd.sun.star.script:Standard.cheia.TelaInteiraLigar?language=Basic&location=application.
    Mensagem: The following Basic script could not be found:
    library: 'Standard'
    module: 'cheia'
    method: 'TelaInteiraLigar'
    location: 'application'

Os pc’s são da mesma empresa e possuem variações da versão do software, mas um PC com a mesma versão teve o mesmo erro.

Os macros estão funcionando perfeitamente e com a segurança em “Baixa”.

---

RESOLVIDO: Era um simples problema da biblioteca de Macros que não estava salva na biblioteca do arquivo, e sim na minha máquina.

[schiavinatto]

ATENÇÃO Segurança em macros Baixa é perigoso, use Média.

Verifica, nos computadores que acusaram erro, em: Ferramentas / Opções / LibreOffice / Avançado, em funcionalidades ativar as duas.