combobox obter valores

editar

Olá,

A rotina abaixo é um costura de diversos "retalhos" de códigos da ajuda do LibreOffice.

Mostra uma forma de carregar os dados da "Planilha1", mais precisamente os que estão em "A1:A10", e inserí-los no combobox do diálogo.

Os requisitos para funcionar são:

• Planilha chamada "Planilha1" com o intervalo "A1:A10" preenchido;
• Um diálogo chamado "Dialog1";
• Uma caixa de combinação chamada "ComboBox1".

...

REM  *****  BASIC  *****

'Declarar Objetos
Dim oDialogo as Object
Dim oComboBox as Object

Sub Iniciar_Dialogo
Dim Inc as Integer
Dim sItem as String

  'Carregar o diálogo
   oDialogo = CarregarDialogo( "Standard", "Dialog1" )

  'Iniciar os controles
   oComboBox = oDialogo.GetControl( "ComboBox1" )

  'Povoar a Caixa de Combinação    
   For Inc = 9 to 0 step -1    
      sItem = ThisComponent.Sheets.getByName("Planilha1").getCellByPosition( 0,Inc ).String
      oComboBox.additem( sItem,0 )
   Next Inc

  'Exibir o diálogo
   oDialogo.Execute()
End Sub

   'Função global para carregar diálogos 
Function CarregarDialogo(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    CarregarDialogo() = oRuntimeDialog
End Function

At.te,
Grafeno