How to program / draw a square spiral? [closed]

edit

Hello @Chistabo,

+1 for nice idea:)

The following method shows how you could draw such a spiral in Calc:

NB. Modified version 29 dec 2017

Sub Calc_Spiral( strStartingCell$, iStartingNumber%, iMaxCount%, iStep%, iStartingDirection%, bClockwise As Boolean, bSecond As Boolean )
REM https://ask.libreoffice.org/en/question/141581/how-to-program-draw-a-square-spiral/
REM <strStartingCell> : A single cell address, e.g. "H12" representing the center of the spiral.
REM <iStartingNumber> : Integer to be displayed inside the starting cell; Incremented by 1 for each following cell.
REM <iMaxCount>       : The total amount of cells to be drawn in the spiral;
REM                     NB. Cells that fall outside of the Sheet''s edges are not counted in the total amount.
REM <iStep>           : Integer increase of the armlength after each turn in the spiral.
REM <iStartingDirection> : Determines the direction of the second cell to be drawn, relative to the starting cell.
REM                        0=RIGHT ; 1=UP ; 2=LEFT ; 3=DOWN.
REM <bClockwise>      : Boolean indicating whether the spiral goes clockwise ( <True> ) or counter-clockwise ( <False> ).
REM <bSecond>         : If <True> , the armlength increases only every second turn instead of every turn.
REM Example call :  Calc_Spiral( "H12", 1, 100, 1, 2, True, True )
    On Local Error Resume Next
    Dim oSheet As Object : oSheet = ThisComponent.CurrentController.ActiveSheet
    Dim oCell As Object  : oCell  = oSheet.getCellRangeByName( strStartingCell )
    Dim iColumn As Integer : iColumn = oCell.getRangeAddress().StartColumn
    Dim iRow As Integer  : iRow = oCell.getRangeAddress().StartRow
    Dim m As Integer     : m = 1 : If bClockwise Then m = 3
    Dim iCount As Integer: iCount = 0
    Dim iDirection%      : iDirection = iStartingDirection
    Dim iCurrentStep%    : iCurrentStep = iStep
    Dim iCurrentPos%     : iCurrentPos = 0
    Dim iArmCount%
'   If iCurrentStep = 0 Then iCurrentStep = 1 '
    Dim rBorder

    Do While iCount < iMaxCount
        oCell.setValue( iStartingNumber + iCount )      REM Display the index number inside the cell.
        oCell.CellBackColor = RGB( 230, 220, 210 )      REM Set the background color for the cell.
    '   oCell.CellBackColor = RGB( 255-iCount, 255-iCount, 255-iCount ) REM This only works for iMaxCount<=256.

    REM Setting individual cell borders; Takes much more time...
        rBorder = oCell.BottomBorder : rBorder.LineWidth = 1
        oCell.BottomBorder = rBorder : oCell.TopBorder = rBorder
        oCell.RightBorder = rBorder  : oCell.LeftBorder = rBorder

        If iCurrentPos   = iCurrentStep Then         REM End of Arm reached:
            iArmCount    = iArmCount + 1
            iDirection   = ( iDirection + m ) Mod 4  REM Compute the Next direction.
            iCurrentPos  = 0
            If Not bSecond Or ( iCount > 0 And iArmCount Mod 2 = 0 ) Then iCurrentStep = iCurrentStep + iStep
        End If

        Select Case iDirection
        Case 0  REM Right
            iColumn = iColumn + 1
        Case 1  REM Up
            iRow = iRow - 1
        Case 2  REM Left
            iColumn = iColumn - 1
        Case 3  REM Down
            iRow = iRow + 1
        End Select
        oCell    = oSheet.getCellByPosition( iColumn, iRow )    REM Go towards the Next Cell.
        iCurrentPos = iCurrentPos + 1
        iCount      = iCount + 1

    Loop
End Sub

Hope you can use it,

With Regards, lib

A few years ago I was inspired by an old friend starting an email exchange about the so called Ulam-spiral to do some experiments on it in Calc.
For that purpose I designed and used an explicit formula to assign the correct serial number to any cell described by its (x|y) [x to the right, y downwards] coordinates with respect to the centre being (0|0). You may have a look into the reduced example here. Since I oiriginally had populated a square of 121x121 the original file was to large for uploading to this site. I reduced it. The primes you find there I did not reduce. They were created using the sieve of Eratosthenes.