Problem with converting a text document to a table

edit

Posting as an answer to this comment:

I am unable to reset the tabs to a single tab

Here is a macro from Andrew Pitonyak's Useful Macro Information for OpenOffice.org to remove empty space, including squeezing multiple tabs to a single one:

Function IsAnythingSelected(oDoc As Object) As Boolean
  Dim oSels  'All of the selections
  Dim oSel         'A single selection
  Dim oCursor      'A temporary cursor

  IsAnythingSelected = False
  If IsNull(oDoc) Then Exit Function
  ' The current selection in the current controller. 
  'If there is no current controller, it returns NULL.
  oSels = oDoc.getCurrentSelection()
  If IsNull(oSels) Then Exit Function

  REM I have never seen a selection count of zero
  If oSels.getCount() = 0 Then Exit Function

  REM If there are multiple selections, then certainly 
  REM something is selected
  If oSels.getCount() > 1 Then 
    IsAnythingSelected = True
  Else
    REM If only one thing is selected, however, then check to see 
    REM if the selection is collapsed. In other words, see if the 
    REM end location is the same as the starting location.
    REM Notice that I use the text object from the selection object
    REM because it is safer than assuming that it is the same as the
    REM documents text object.
    oSel = oSels.getByIndex(0)
    oCursor = oSel.getText().CreateTextCursorByRange(oSel)
    If Not oCursor.IsCollapsed() Then IsAnythingSelected = True
  End If
End Function

Function GetLeftMostCursor(oSel As Object) As Object
  Dim oRange   'Left most range.
  Dim oCursor  'Cursor at the left most range.

  If oSel.getText().compareRegionStarts(oSel.getEnd(), oSel) >= 0 Then
    oRange = oSel.getEnd()
  Else
    oRange = oSel.getStart()
  End If
  oCursor = oSel.getText().CreateTextCursorByRange(oRange)
  oCursor.goRight(0, False)
  GetLeftMostCursor = oCursor
End Function

Function GetRightMostCursor(oSel As Object) As Object
  Dim oRange   'Right most range.
  Dim oCursor  'Cursor at the right most range.

  If oSel.getText().compareRegionStarts(oSel.getEnd(), oSel) >= 0 Then
    oRange = oSel.getStart()
  Else
    oRange = oSel.getEnd()
  End If
  oCursor = oSel.getText().CreateTextCursorByRange(oRange)
  oCursor.goLeft(0, False)
  GetRightMostCursor = oCursor
End Function

Function CreateSelectedTextIterator(oDoc As Object, sPrompt As String, oCurs()) As Boolean
  Dim lSelCount As Long       'Number of selected sections.
  Dim lWhichSelection As Long 'Current selection item.

  Dim oSels  'All of the selections
  Dim oSel         'A single selection.
  Dim oLCurs     'Cursor to the left of the current selection.
  Dim oRCurs     'Cursor to the right of the current selection.

  CreateSelectedTextIterator = True
  If Not IsAnythingSelected(ThisComponent) Then
    Dim i%
    i% = MsgBox("No text selected!" + Chr(13) + sPrompt, _
      1 OR 32 OR 256, "Warning")
    If i% = 1 Then
      oLCurs = oDoc.getText().createTextCursor()
      oLCurs.gotoStart(False)
      oRCurs = oDoc.getText().createTextCursor()
      oRCurs.gotoEnd(False)
      oCurs = DimArray(0, 1)
      oCurs(0, 0) = oLCurs
      oCurs(0, 1) = oRCurs
    Else
      oCurs = DimArray()
      CreateSelectedTextIterator = False
    End If
  Else
    oSels = ThisComponent.getCurrentSelection()
    lSelCount = oSels.getCount()
    oCurs = DimArray(lSelCount - 1, 1)
    For lWhichSelection = 0 To lSelCount - 1
      oSel = oSels.getByIndex(lWhichSelection)
      REM If I want to know if NO text is selected, I could
      REM do the following:
      REM oLCurs = oSel.getText().CreateTextCursorByRange(oSel)
      REM If oLCurs.isCollapsed() Then ...
      oLCurs = GetLeftMostCursor(oSel)
      oRCurs = GetRightMostCursor(oSel ...