BASIC+Calc: how to check assigned password

[lonk]

How can I check the password of this active sheet ?
I think it is impossible for it is the security reason.

Now I use:

REM  *****  BASIC  *****
Option Explicit
Global sPassword As String

Sub LockActiveSheet
	Dim oSheet As Object : oSheet = ThisComponent.CurrentController.ActiveSheet
	sPassword = "1234"
'	Lock active sheet   '
	oSheet.Protect(sPassword)
End Sub

Sub CheckCorrectPassword
	Dim oSheet As Object : oSheet = ThisComponent.CurrentController.ActiveSheet
	oSheet.UnProtect(sPassword)
	oSheet.getCellByPosition(0, 0).setString("X")
	If 	oSheet.getCellByPosition(0, 0).String = "X" Then
		MsgBox "Password is correct.", , ""
		oSheet.Protect(sPassword)		
	Else
		MsgBox "Password is not correct.", , ""
	End If
End Sub

In the example, I have to interfere a cell in the active sheet.

Are there any ways to make it shorter and without touching even a cell ?

[karolus]

Code edited for readability

[erAck]

You could ask boolean oSheet.isProtected(). However, calling unprotect() with a wrong password will already throw lang::IllegalArgumentException that results in a BASIC runtime error. So usual BASIC error handling is applicable, like

On Error Goto ErrorHandler
oSheet.unprotect(sPassword)
print oSheet.isProtected()
REM do something good
Exit Sub
ErrorHandler:
MsgBox "Password is not correct.", , ""

[lonk]

Dear @erAck,

Thank you so much, hereunder code is just a memo.

Sub CheckCorrectPassword
	Dim oSheet As Object : oSheet = ThisComponent.CurrentController.ActiveSheet
	oSheet.unprotect(sPassword)
	If 	oSheet.isProtected() = False Then	
		MsgBox "Password is correct.", , ""
		oSheet.protect(sPassword)
	Else
		MsgBox "Password is not correct.", , ""
	End If
End Sub

[erAck]

It will not work if unprotect() fails due to a wrong password. Read what I wrote about it throwing an exception resulting in a BASIC error. The following isProtected() isn’t even executed in that case.