Numeração de linhas Calc LibreOffice

editar

Segue código para preenchimento de valores em células utilizando o laço "For": Coloquei um preenchimento até 1.000 para não pesar o processamento, mas caso queira algo acima desse valor é só modificar

Sub PreencherCelula
Dim oDoc as Object 
dim oPlan As Object 
Dim oCel As Object 
Dim i As Long  

    oDoc = ThisComponent
    oPlan = oDoc.getSheets().getByIndex ( 0 )

    For i = 0 To 1000 ' Altere o valor de acordo com sua necessidade
        oCel = oPlan.getCellByPosition ( 0 , i )
        oCel.setValue( i )      
    Next i 
    Print "Concluído"
End Sub

Link para o arquivo: C:\fakepath\PreencherLinhas.ods

Para quem quiser uma macro para enumerar a partir de uma célula até a ÚLTIMA LINHA USADA e adicionar em um botão, segue abaixo uma que pode ajudar:

SUB ENUMERAR
dim primeiraCelula as string, oColuna as string, nomePlanilha as string
dim iniciarNumero as integer
dim oCel as object, oCel2 as string
Dim oCurs As object
Dim LastRow&

primeiraCelula = "A7" 'nome da primeira celula'
oColuna = "A" 'nome da coluna para enumerar'
nomePlanilha = "ALFA" 'nome da planilha a enumerar'
iniciarNumero = 1 'numero para iniciar a enumeracao'
oCel2 = "B7" 'selecionar celula apos a enumeracao'

oCurs = ThisComponent.Sheets.GetByName(nomePlanilha).createCursor()
oCurs.gotoEndOfUsedArea(False)
LastRow = oCurs.getRangeAddress().EndRow + 1

oCel = ThisComponent.Sheets.getByName(nomePlanilha).getCellRangeByName(primeiraCelula)
oCel.setValue(iniciarNumero)
rem define variables
dim document   as object
dim dispatcher as object

document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "ToPoint"
args1(0).Value = primeiraCelula
dispatcher.executeDispatch(document, ".uno:GoToCell", "", 0, args1())

dim args3(0) as new com.sun.star.beans.PropertyValue
args3(0).Name = "EndCell"
args3(0).Value = "" & oColuna & "" & LastRow & ""
dispatcher.executeDispatch(document, ".uno:AutoFill", "", 0, args3())

dim args4(0) as new com.sun.star.beans.PropertyValue
args4(0).Name = "ToPoint"
args4(0).Value = oCel2
dispatcher.executeDispatch(document, ".uno:GoToCell", "", 0, args4())

end sub

Preencher apenas o dados iniciais (primeiraCelula, oColuna, nomePlanilha, iniciarNumero, oCel2)

Valeu Oliver. Muito obrigado por esta dica tão boa. Um grande abraço!!