Comando para Maximizar tela do LibreOffice.

Alguém conhece o comando, via Basic, de Maximizar a tela do LIbreOffice.

Oi Schiavinatto.

Não sei se é isso que você quer, mas as macros abaixo servem respectivamente para desligar e ligar os painéis do CALC:

   sub LimpaTela
rem ----------------------------------------------------------------------
rem define variaveis
dim document   as object
dim dispatcher as object
rem ----------------------------------------------------------------------
rem Obtém acesso ao documento
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

rem ----------------------------------------------------------------------
dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "ViewRowColumnHeaders"
args1(0).Value = false
   dispatcher.executeDispatch(document, ".uno:ViewRowColumnHeaders", "", 0, args1())

rem ----------------------------------------------------------------------
dim args2(0) as new com.sun.star.beans.PropertyValue
args2(0).Name = "InputLineVisible"
args2(0).Value = false
    dispatcher.executeDispatch(document, ".uno:InputLineVisible", "", 0, args2())

rem ----------------------------------------------------------------------
dim args3(0) as new com.sun.star.beans.PropertyValue
args3(0).Name = "StatusBarVisible"
args3(0).Value = false
    dispatcher.executeDispatch(document, ".uno:StatusBarVisible", "", 0, args3())
rem ----------------------------------------------------------------------
dispatcher.executeDispatch(document, ".uno:ToggleSheetGrid", "", 0, Array())
   
end sub


sub RecuperaTela
rem ----------------------------------------------------------------------
rem define variáveis
dim document   as object
dim dispatcher as object
rem ----------------------------------------------------------------------
rem Toma o controle do documento
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

rem ----------------------------------------------------------------------
dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "InputLineVisible"
args1(0).Value = true
    dispatcher.executeDispatch(document, ".uno:InputLineVisible", "", 0, args1())

rem ----------------------------------------------------------------------
dim args2(0) as new com.sun.star.beans.PropertyValue
args2(0).Name = "StatusBarVisible"
args2(0).Value = true
    dispatcher.executeDispatch(document, ".uno:StatusBarVisible", "", 0, args2())

rem ----------------------------------------------------------------------
dispatcher.executeDispatch(document, ".uno:ToggleSheetGrid", "", 0, Array())

end sub

Ah, e se você quer TELA INTEIRA, inclua isso para Ativar:

dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "FullScreen"
args1(0).Value = true
    dispatcher.executeDispatch(document, ".uno:FullScreen", "", 0, args1())

E isso para desativar (ficará acessível o botão flutuante TELA INTEIRA, que pode ser clicado em qualquer momento):

dim args2(0) as new com.sun.star.beans.PropertyValue
args2(0).Name = "FullScreen"
args2(0).Value = false
    dispatcher.executeDispatch(document, ".uno:FullScreen", "", 0, args2())

Ola @Jedison, estes comando os conheço, o FullScrren, tira o Menu e as Barras de ferramenta etc… Só necessito realmente Maximizar a tela que esta visível.

Tenho esta macro para tela inteira ( chamo de Modo Aplicativo ) toda navegação entre planilhas é necessário Botões/macros ou Hiperligações.

Continua

Continuação

Sub FullScreenON
' xplan = planilha de aberura ( menu do arquivo )
' xtitulo = título que mostra no cabeçãlho da tela
'Para abrir TELA INTEIRA na abertura do arquivo
'Ferramentas / Personalizar / Eventos
'Ao abrir documento
'ligar a MACRO ok.
Dim oSheet As Object
Dim oController As Object
dim args2(0) as new com.sun.star.beans.PropertyValue : args2(0).Name = "FullScreen" : args2(0).Value = true
CreateUnoService("com.sun.star.frame.DispatchHelper").executeDispatch(ThisComponent.CurrentController.Frame, ".uno:FullScreen", "", 0, args2())
With ThisComponent.CurrentController
.setActiveSheet(ThisComponent.Sheets.getByName( "Planilha" )) '<== Planilha a Visualizar Inicialmente.
.ColumnRowHeaders = False
.SheetTabs = False
.Frame.LayoutManager.HideCurrentUI = True
.HorizontalScrollBar = False
.VerticalScrollBar = False 
'.Frame.Title = "Título no modo Aplicativo"
end With
end Sub

E esta para voltar ao normal ( Modo Edição )

Sub FullScreenOFF
Dim oController As Object
dim args2(0) as new com.sun.star.beans.PropertyValue : args2(0).Name = "FullScreen" : args2(0).Value = false
CreateUnoService("com.sun.star.frame.DispatchHelper").executeDispatch(ThisComponent.CurrentController.Frame, ".uno:FullScreen", "", 0, args2())
With ThisComponent.CurrentController
.ColumnRowHeaders = True
.SheetTabs = True
.Frame.LayoutManager.HideCurrentUI = False
.HorizontalScrollBar = False
.VerticalScrollBar = False 
.Frame.ComponentWindow.SetFocus() '<<<< Devolver o foco a janela <<<<'
End With
End Sub

Olá @Jedison,

Encontrei aqui: Open Spreadsheet Mimimised - BASIC

Dei uma tirada de “gordura”

Sub Maximized
    ThisComponent.getCurrentController().getFrame().ContainerWindow.IsMaximized = True
End Sub

Sub Minimized
    ThisComponent.getCurrentController().getFrame().ContainerWindow.IsMinimized = True
End Sub

Show de bola!!!