Insertar imagen en la cabecera en una posicion determinada

[tupc.net]

Quiero insertar una imagen en Writer en la cabecera o en el pié de página, estoy usando este código:

Sub Main
Dim oText, Curs, objTextGraphicObject As Object
Dim FileName, FileURL
oText = ThisComponent.Text
Curs = oText.createTextCursor
Curs.gotoStart(False)
Curs.gotoNextParagraph(False)
Curs.gotoEndofParagraph(False)

FileName = “C:\Imagenes\Imagen1.png”
FileURL = convertToURL(FileName)

objTextGraphicObject = ThisComponent.createInstance(“com.sun.star.text.TextGraphicObject”)
Dim objSize as New com.sun.star.awt.Size
objSize.Width = 4900
objSize.Height = 4900
objTextGraphicObject.setSize(objSize)
objTextGraphicObject.AnchorType = com.sun.star.text.TextContentAnchorType.AT_CHARACTER
objTextGraphicObject.GraphicURL = FileURL
oText.insertTextContent(Curs.Start, objTextGraphicObject, false)

Con esto la inserto en el cuerpo del documento, pero quiero insertarla en la cabecera para que se repita en las páginas derechas a modo de logo, tambien me gustaría establecer el sitio concreto donde ha de ir coordenadas x e y, ya que iré insertando diversas imágenes y no se deben solapar

¿Hay alguna forma de hacer esto?
Gracias

[elmau]

Es importante que tengas tus estilos de página correctamente definidos para esto… en el siguiente ejemplo, asumo que estas usando el formato predeterminado de página.

Debes de acceder al texto del encabezado y ahí insertar.

Sub main()
Dim Size as New com.sun.star.awt.Size

	'El estilo de tu página
	mi_estilo = "Standard"
	'El tamaño de la imagen
	Size.Height = 500
	Size.Width = 1000

	doc = ThisComponent
	style = doc.StyleFamilies.getByName("PageStyles").getByName(mi_estilo)
	
	'Nos aseguramos de activar los encabezados
	style.HeaderIsOn = True
	'Accedemos al texto del encabezado
	text = style.HeaderText

	obj = doc.createInstance("com.sun.star.text.TextGraphicObject")
	'La ruta bebe estar en formaro URL
	obj.GraphicURL = "file:///home/mau/Pictures/mauflix.jpg"
	obj.Size = Size
	obj.AnchorType = com.sun.star.text.TextContentAnchorType.AS_CHARACTER
	text.insertTextContent(text.Start, obj, False)
	
End Sub

[tupc.net]

Perfecto, eres un máquina, solo me falta como posicionar la imagen

[tupc.net]

Lo encontre!!!

obj.LeftMargin = 4000
obj.TopMargin = 1000

Muchísimas gracias elmau