Afficher ou récupérer un Valeur selon 3 critères

[Ricaboudpa]

Bonjour,
J’utilise LibreOffice Calc 7.5.2 en français.
Je n’arrive pas à récupérer une valeur de manière dynamique répondant à 3 critères.
Je voudrais récupérer sur l’onglet 01 la valeur contenu sur l’onglet 03 dans la colonne nommé “crédit” si elle répond au critère suivant qu’elle soit comprise en la date >= 23 du mois précédent et <= 09, que les cellules des colonne typesMouvement et catégorieMouvement contiennent “recette”, “salaire”

Je place la formule que j’ai tester. =SI(ET(typesMouvement="Recette";catégoriesMouvement="salaire";dateMouvement>=DATE(23/12/2021);dateMouvement>=DATE(9/1/2022));"crédit")

Et la formule que j’ai corrigé.

=SI(ET($tblrap.typesmouvement="Recettes";$tblrap.catégoriesmouvement="salaire";$tblrap.datemouvement>=DATE(2022;4;23);$tblrap.datemouvement<=DATE(2022;5;9));"crédit";"Vides")

Par contre je ne sais pas pourquoi mais $tblrap devrais être écrit comme ceci $TblRap de même que catégoriesMouvement et dateMouvement.

Je ne sais pas si c’est suffisamment claire pour vous.
WIP_Maquette_2022-2023 - Anonyme.ods (83.4 KB)

[njhub]

Bonjour Ricaboudpa
#R1#
la fonction SOMME.SI.ENS() nécessite des zones d’étendues similaires,
pour l’exemple les plages nommées sont limitées de la ligne 5 à la ligne 1002

la somme des salaires est obtenue par les formules suivantes en feuille “Feuille5”,

quand vous voulez utiliser une date :
13 493,11 €
=SOMME.SI.ENS(crédit;dateMouvement;">="&"31/03/2022";dateMouvement;"<="&"31/12/2022";typesMouvement;"Recettes";catégoriesMouvement;"salaire")

quand vous voulez utiliser la fonction DATE() :
13 493,11 €
=SOMME.SI.ENS(crédit;dateMouvement;">="&DATE(2022;3;31);dateMouvement;"<="&DATE(2022;12;31);typesMouvement;"Recettes";catégoriesMouvement;"salaire")

#R2#
Pour les recettes en 2022, utilisez en 2022.C6 la formule suivante:

=SOMME.SI.ENS($Sheet0.$D$11:$D$816;$Sheet0.$A$11:$A$816;">="&DATE(2022;COLONNE()-2;1);$Sheet0.$A$11:$A$816;"<="&FIN.MOIS(DATE(2022;COLONNE()-2;1);0);$Sheet0.$E$11:$E$816;$B6)

en 2023 les recettes commencent en 2023.C5 avec la formule :

=SOMME.SI.ENS($Sheet0.$D$11:$D$816;$Sheet0.$A$11:$A$816;">="&DATE(2023;COLONNE()-2;1);$Sheet0.$A$11:$A$816;"<="&FIN.MOIS(DATE(2023;COLONNE()-2;1);0);$Sheet0.$E$11:$E$816;$B5)

Pour les dépenses en 2022, utilisez en 2022.C17 la formule suivante:

=SOMME.SI.ENS($Sheet0.$C$11:$C$816;$Sheet0.$A$11:$A$816;">="&DATE(2022;COLONNE()-2;1);$Sheet0.$A$11:$A$816;"<="&FIN.MOIS(DATE(2022;COLONNE()-2;1);0);$Sheet0.$E$11:$E$816;$B17)

et en 2023.C16 :
=SOMME.SI.ENS($Sheet0.$C$11:$C$816;$Sheet0.$A$11:$A$816;">="&DATE(2023;COLONNE()-2;1);$Sheet0.$A$11:$A$816;"<="&FIN.MOIS(DATE(2023;COLONNE()-2;1);0);$Sheet0.$E$11:$E$816;$B16)

Ricaboudpa-WIP_Maquette_2022-2023.ods (78,7 Ko)

[Ricaboudpa]

bonjour @njhub
Désolé j’aurais du vraiment être plus précis.
J’aimerais récupérer uniquement la valeur correspondant à salaire pour remplir dynamiquement le tableau qui ce trouve dans l’onglet 2022.
L’idée est que l’onglet TblRap remplis dynamiquement le tableau de l’onglet 2022 au fur et à mesure des pointage.
Le salaire tombe entre le 23 et le 9. mais c’est le même raisonnement pour les différentes factures .

Après peut être que je m’y prend mal.
Merci de l’intérêt que tu portes à mon problème.
A+