How to create a SequenceInputStream from Delphi code?

[pleriche]

Hi,

I have integrated LibreOffice into our Delphi application and would like to load documents directly from memory. For that I need to create a SequenceInputStream and then populate it with the raw file data.

I can create the SequenceInputStream without issue, but for the life of me I cannot figure out how to populate it from e.g. an array of bytes. Here is a small test case:

program SequenceInputStream;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, System.Win.ComObj, Winapi.ActiveX;

var
  ServiceManager: Variant;

function CreateSequenceInputStreamFromByteArray(const AByteArray: TBytes): Variant;
var
  LVariantByteArray: Variant;
begin
  LVariantByteArray := AByteArray;

  Result := ServiceManager.createInstance('com.sun.star.io.SequenceInputStream');

  //EOleError with message 'Method 'createStreamFromSequence' not supported by automation object'.
  Result.createStreamFromSequence(LVariantByteArray);

  //EOleException with message 'com.sun.star.lang.IllegalArgumentException: Wrong number of arguments!'.
  Result.initialize(LVariantByteArray);
end;

var
  LByteArray: TBytes;
  LMyStream: Variant;
begin
  CoInitialize(nil);

  ServiceManager := CreateOleObject('com.sun.star.ServiceManager');

  try
    SetLength(LByteArray, 10000);

    LMyStream := CreateSequenceInputStreamFromByteArray(LByteArray);

  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

According to the documentation there should be a “createStreamFromSequence” method, but that doesn’t seem accessible. If It try to call it it returns the error ‘Method ‘createStreamFromSequence’ not supported by automation object’.

“intialize” is available, but it doesn’t accept the array of bytes in any format that I have tried. The error message is ‘com.sun.star.lang.IllegalArgumentException: Wrong number of arguments!’.

Does anyone know how to populate a SequenceInputStream via Delphi code?

Thanks!

[mikekaganski]

Accessing UNO services

This specific case is explained in Service Constructors section of DevGuide. When you see member functions in a service definition (as opposed to interface definition; these in service definition have no return type), it’s a constructor, which must be used as x = qualified.service.Name.constructorName(arguments) In this case, both constructors internally create an instance of the service, and then call its initialize method, passing the arguments they take, as an array of any. Basically, you m…

I don’t know how exactly service constructors are exposed in Delphi, so you have to find out yourself. That would be the easiest, because it directly takes a sequence of bytes.

If you want to use initialize, it is implemented here, and you can see that you need to pass an array of anys (with exactly one any, holding the array).

Or, if you have access to something like Basic’s CreateUnoServiceWithArguments, use that, with the same structure of the argument.

[sokol92]

@mikekaganski

don’t know how exactly service constructors are exposed in Delphi

The following VBA macro fails with an error:

Sub TestCreateSequenceInputStreamFromByteArray()
  Dim aData(20) As Byte, v
  Dim oSM As Object, oSIS As Object
  Set oSM = CreateObject("com.sun.star.ServiceManager")
  Set oSIS = oSM.createInstanceWithArguments("com.sun.star.io.SequenceInputStream", Array(aData))
  Set oSM = Nothing
End Sub

[mikekaganski]

@sokol92 maybe you get not an array of anys from Array(aData)?

[sokol92]

I did it in analogy with this topic.

[mikekaganski]

Microsoft Visual Basic? I have no idea how the bridge will work from there. I very much suspect that no, that doesn’t coerce to array(any).

[sokol92]

@mikekaganski

Microsoft Visual Basic?

This is an optical illusion - a message from VBA.
Some time ago the guys from MS forgot to fix it.

[mikekaganski]

As I suspected, the problem was type mismatch, although on a lower level: aData arrived as []any, not as the expected []byte.

This is what is needed here:

Sub TestCreateSequenceInputStreamFromByteArray()
  Dim aData(20) As Byte
  Dim oSM As Object, oSIS As Object, oStrictlyTypedUnoValue As Object
  Set oSM = CreateObject("com.sun.star.ServiceManager")
  Set oStrictlyTypedUnoValue = oSM.Bridge_GetValueObject()
  oStrictlyTypedUnoValue.Set "[]byte", aData
  Set oSIS = oSM.createInstanceWithArguments("com.sun.star.io.SequenceInputStream", Array(oStrictlyTypedUnoValue))
  Set oSM = Nothing
End Sub

[pleriche]

I would not have guessed that in a million years. Thank you very much, it works perfectly!

For anyone else who may stumble upon this question in future, here is the Delphi code to load a document directly from memory:

function LoadLibreOfficeDocumentFromMemory(const ADocumentFileData: TBytes): Variant;
var
  LServiceManager, LStrictlyTypedUnoValue, LInputStream, LDesktop: Variant;
  LArgumentsArray, LPropertyArray: TArray<Variant>;
begin
  LServiceManager := CreateOleObject('com.sun.star.ServiceManager');

  {A SequenceInputStream is used to load the document from memory.  In order to get the bytes into the
  SequenceInputStream the initialize method is called.  This method takes an array of arguments, in which it
  expects to find a single entry which must be a strictly typed uno value - a byte array.}

  {Create the argument array for SequenceInputStream.initialize}
  LStrictlyTypedUnoValue := LServiceManager.Bridge_GetValueObject;
  LStrictlyTypedUnoValue.Set('[]byte', Variant(ADocumentFileData));
  SetLength(LArgumentsArray, 1);
  LArgumentsArray[0] := LStrictlyTypedUnoValue;

  {Create and initialize the SequenceInputStream}
  LInputStream := LServiceManager.createInstance('com.sun.star.io.SequenceInputStream');
  LInputStream.initialize(Variant(LArgumentsArray));

  {Specify the stream to load from in the property array for loadComponentFromURL.}
  SetLength(LPropertyArray, 1);
  LPropertyArray[0] := LServiceManager.Bridge_GetStruct('com.sun.star.beans.PropertyValue');
  LPropertyArray[0].Name := 'InputStream';
  LPropertyArray[0].Value := LInputStream;

  {Load and display the document}
  LDesktop := LServiceManager.createInstance('com.sun.star.frame.Desktop');
  Result := LDesktop.loadComponentFromURL('private:stream', '_blank', 0, Variant(LPropertyArray));
end;

[sokol92]

@mikekaganski

This is what is needed here:

But I didn’t read to this point.

[pleriche]

Guys, thank you for your help.

Delphi uses OLE Automation to interface with LibreOffice, just like Visual Basic. If there’s a working Visual Basic example somewhere I am confident I can translate that to Delphi.

I have now also tried the following:

function CreateSequenceInputStreamFromByteArray(const AByteArray: TBytes): Variant;
var
  LVariantByteArray: Variant;
begin
  LVariantByteArray := AByteArray;
  Result := ServiceManager.createInstanceWithArguments('com.sun.star.io.SequenceInputStream', LVariantByteArray); //EOleException with message 'com.sun.star.lang.IllegalArgumentException: Wrong number of arguments!'
end;

This yields an error “EOleException with message ‘com.sun.star.lang.IllegalArgumentException: Wrong number of arguments!’.”

This made me think that perhaps I should not pass the array of bytes directly, but instead make the array of bytes an element in an outer array of length 1, like this:

function CreateSequenceInputStreamFromByteArray(const AByteArray: TBytes): Variant;
var
  LVariantByteArray, LVariantByteArrayArray: Variant;
  LVariantArray: TArray<Variant>;
begin
  LVariantByteArray := AByteArray;
  SetLength(LVariantArray, 1);
  LVariantArray[0] := LVariantByteArray;
  LVariantByteArrayArray := LVariantArray;

  Result := ServiceManager.createInstanceWithArguments('com.sun.star.io.SequenceInputStream', LVariantByteArrayArray); //com.sun.star.lang.IllegalArgumentException: Unexpected type of argument!
end;

With this I see a similar error to the one you’re seeing with the VB code: “EOleException with message ‘com.sun.star.lang.IllegalArgumentException: Unexpected type of argument!’”

Calling “initialize” with the array inside an array, which I am guessing is equivalent to the above, also gives the same error:

  Result := ServiceManager.createInstance('com.sun.star.io.SequenceInputStream');
  Result.initialize(LVariantByteArrayArray); //com.sun.star.lang.IllegalArgumentException: Unexpected type of argument!

I notice in the documentation you linked to above that SequenceInputStream is referred to as a “New-style service”. Since OLE Automation is quite old and I guess not very popular nowadays, is it possible that the OLE Automation code on the LibreOffice side hasn’t been updated to support this functionality?

[elmau]

I do it this way in Python, I don’t know how to migrate this to Delphi.

    def input(buffer):
        service = 'com.sun.star.io.SequenceInputStream'
        stream = create_instance(service, True)
        stream.initialize((uno.ByteSequence(buffer.getvalue()),))
        return stream

[karolus]

@elmau

create_instance

@elmau
I can guess how create_instance is defined, but dont have an idea about the buffer-object??

[elmau]

Look:

io — Core tools for working with streams

[karolus]

@elmau

Look:

Blame on me!

[pleriche]

From my understanding there are several language bridges. There is one for C++, one for Python and there is also an OLE Automation bridge that is used by Visual Basic and Delphi. Sometimes the way you interact with these bridges differ in subtle ways, as is apparently the case here: Try as I might I have not been able to find the equivalent OLE Automation syntax for your Python code.