Organizando Planilhas

[andretross]

Como faz para organizar planilhas em Ordem Alfabética?

[schiavinatto]

Ola @andretross, seja bem vindo aoGrupo.

A macro abaixo esta em VBA porém funciona no LibreOffice Basic.

Rem Attribute VBA_ModuleType=VBADocumentModule
Option VBASupport 1
Option Explicit
'===================================================|
Sub PlanilhasOrdenarPelosNomes()
' Código para ordenação das planilhas de um arquivo
'===================================================|
Dim k           As Integer
Dim i           As Integer
Dim Tipo        As Integer
Dim Mensagem    As String
'Exibir caixa de mensagem para que o usuário possa selecionar o tipo de ordenação desejada
Mensagem = "Pressione Sim para ordenação crescente" & vbLf & _
"e Não para ordenação decrescente"
Tipo = MsgBox(Mensagem, vbYesNo + vbApplicationModal, _
"Ordenar planilhas")
Select Case Tipo
Case vbYes
    'Opção de ordenação crescente
    For k = 1 To ThisWorkbook.Sheets.Count
        For i = 1 To ThisWorkbook.Sheets.Count - 1
            If Sheets(i).Name > Sheets(i + 1).Name Then
            Sheets(i + 1).Move Before:=Sheets(i)
            End If
        Next i
    Next k
Case vbNo
'Opção de ordenação decrescente
    For k = 1 To ThisWorkbook.Sheets.Count
        For i = 1 To ThisWorkbook.Sheets.Count - 1
            If Sheets(i).Name < Sheets(i + 1).Name Then
            Sheets(i + 1).Move Before:=Sheets(i)
            End If
        Next i
    Next k
End Select
End Sub

---

ATENÇÂO:: Caso queira dar mais detalhes a sua pergunta, use na pergunta ou abaixo. Grato.

Caso a resposta atendeu sua necessidade, por gentileza, click na bolinha a esquerda da resposta, para finalizar a pergunta.