PROCV ou PROCH

[rrjunior]

Se eu tenho uma lista com 20 nomes na coluna B, por exemplo, e de acordo com um critério da coluna A eu quero montar uma nova lista em ordem extraindo só os nomes de acordo com o critério da coluna A, ou seja, eu ficaria com uma lista de menos nomes, mas os mesmos tem que ficar sequencialmente ordenados.
Por exemplo> na coluna A tenho os nomes:
1 Alberto
2 Sidney
1 Maria
1 João
1 Pedro
1 Cecilia
2 Junia
2 Shilrley
2 Dora

Quero montar em uma outra coluna a lista de nomes que tem o numero 2 na coluna A.
O resultado deve ficar assim…sequencialmente sem linhas em branco entre os nomes,ok?
Sidney
Junia
Shirley
Dora

Obrigado
Roberto

[Grafeno]

Mas a PROCV e a PROCH têm a limitação de retornar sempre o primeiro resultado na coluna ou na linha respectivamente. E o que vc está procurando se parece mais com “filtragem” pelo critério “2”.

Talvez fosse melhor vc usar o Filtro Padrão para resolver o problema. Onde é possível inserir o valor “2” como critério, clicar no botão “mais opções”, marcar “Copiar resultados para…” e selecionar a célula a partir da qual serão inseridos os dados filtrados.

At.te,

Grafeno

[Jedison]

Olá Roberto.
Vamos criar uma tabela no Bloco A3:C12, que conterá os dados que você deseja classificar:

Cod   Nome     Ordem
1	Alberto	1
2	Sidney	2
1	Maria	3
1	João         4
1	Pedro	5
1	Cecília	6
2	Junia	7
2	Shilrley	8
2	Dora	        9

Em B17 informaremos o Código que você quer que sejam relacionados os nomes. No seu caso, queres relacionar todos os nomes com o Código 2.

Em B18 vamos criar um campo para determinar quantas ocorrências de Código 2 aparecem na lista, inserindo a função
CONT.SE(A4:A12;B17) - O resultado será 4

Agora vamos gerar a nossa lista classificada no bloco G3:I12, inserindo as seguintes fórmulas:

Fórmulas da coluna “G”

G3  =B18     
G4  =SE(OU(I3="";G3=1;G3="");"";G3-1)
G5  =SE(OU(I4="";G4=1;G4="");"";G4-1)
G6  =SE(OU(I5="";G5=1;G5="");"";G5-1)
(sucessivamente, até)
G12 =SE(OU(I11="";G11=1;G11="");"";G11-1)

Fórmulas da coluna “H”

H3  =SE(I3="";"";PROCV(I3;$B$4:$C$12;2;0))
H4  =SE(I4="";"";PROCV(I4;$B$4:$C$12;2;0))
H5  =SE(I5="";"";PROCV(I5;$B$4:$C$12;2;0))
(sucessivamente, até)
H12 =SE(I12="";"";PROCV(I12;$B$4:$C$12;2;0))

Fórmulas da coluna “I”

I3  =SE(OU(G3=0;G3="");"";PROCV(B$17;A4:B$12;2;0))
I4  =SE(G4="";"";PROCV(B$17;INDIRETO(ENDEREÇO(4+H3;1)&":E12");2;0))
I5  =SE(G5="";"";PROCV(B$17;INDIRETO(ENDEREÇO(4+H4;1)&":E12");2;0))
(sucessivamente, até)
I12  =SE(G12="";"";PROCV(B$17;INDIRETO(ENDEREÇO(4+H11;1)&":E12");2;0))

Aí você escolhe o que vai querer imprimir.

(A postagem ficou com as colunas e linhas truncadas, então note que depois da referência à célula onde você deve inserir as fórmulas, vem a fórmula precedida do sinal de igual. Se não entender, pergunte.

[RudPiva]

Olá.
Segue uma outra forma que talvez lhe sirva.
Na celula D1 coloca o cod que quer filtrar.
Ex:

D1 = 1

Na celula D2 voce coloca a formula:

D2 {=SEERRO(ÍNDICE($A$1:$B$10;MENOR(SE($A$1:$B$10=$D$1;LINHA($A$1:$B$10));LINHA(A1));2);"")}

Na D3

D3 {=SEERRO(ÍNDICE($A$1:$B$10;MENOR(SE($A$1:$B$10=$D$1;LINHA($A$1:$B$10));LINHA(A2));2);"")}

E assim por diante.
Lembrando que para torna-la matricial você tem que pressionar as teclhas Ctrl+Shift+Enter apos o final da formula
ex.ods