Qual função equivalente do Excel no Calc para a função Único

[Csakito]

Olá,
No Excel temos a função único que dada uma lista de valores retorna somente aqueles que não se repetem, existe algo semelhante no Calc?

[schiavinatto]

@Csakito, Para a lista destes únicos use a Macro abaixo:

'====================================================================
sub ExtrairUnicosInputBox ' vai pedir "Planilha1.A1:A8" "Planilha2.A7"
'====================================================================
'fonte:  http://www.clubedohardware.com.br/profile/697345-tiank/
rem ----------------------------------------------------------------------
Dim mCamposFiltro(0) As New com.sun.star.sheet.TableFilterField
Dim x as String
Dim y as String
Dim xi() as Variant
Dim yi() as Variant
   x = inputbox("Área de extração: (Ex: Planilha1.D2:C24)")
   y = inputbox("Célula inicial para descarga: (Ex: Planilha2.C7)") 
      msgbox "Area de extração: "& X &" , Célula inicial para descarga: "& y
   xi = Split( x,"." ) 
   yi = Split( y,"." )
   oPlan = ThisComponent.Sheets.getByName( xi(0) )
   oIntervalo = oPlan.getCellRangeByName( xi(1) )
   '=> esta parte permanece idêntica <=
   'Descritor do filtro
   oDescFiltro = oIntervalo.createFilterDescriptor( True )
    'Definir os campos
   mCamposFiltro(0).Field = 0
   mCamposFiltro(0).Operator = 1
   'Estabelecer o destino
   oPlan = ThisComponent.Sheets.getByName( yi(0) )
   oDestino = oPlan.getCellRangeByName( yi(1) ).getCellAddress()
   '=> Restante permanece igual <=
   'Propriedades do filtro padrão
   oDescFiltro.ContainsHeader = False
   oDescFiltro.SkipDuplicates = True
   oDescFiltro.CopyOutputData = True
   oDescFiltro.OutputPosition = oDestino
   oDescFiltro.FilterFields = mCamposFiltro
   oIntervalo.Filter( oDescFiltro )
end Sub

---

ATENÇÂO:: Para dar mais detalhes a sua pergunta, use na pergunta ou abaixo. Não use Adicionar resposta para comentário. Grato.

Caso a resposta atendeu sua necessidade, por gentileza, click na bolinha a esquerda da resposta, para finalizar a pergunta.