What's the configuration location of "Use LibreOffice dialogues" user preference?

[LibreOfficiant]

Hi

I did not manage to identify which configuration parameter holds “Tools - Options - LibreOffice - General - Open/Save dialogs - Use LO dialogs” user preference.

I went through “Tools - Options - LibreOffice - Advanced - Open Expert Configuration” without success

[mikekaganski]

@LibreOfficiant:

you did a wrong thing here. You had asked a question (“Use LibreOffice dialogs” configuration location), and got an answer. Okay, but then you suddenly provided your own answer, and changed the question’s title “Update “Use LibreOffice dialogues” user preference with script”, so now my answer is no more relevant to what is asked here.

Please don’t do such things. You needed to let this question be as it was, and create another question about scripted update, and add your answer there. Then it would be logical and not confusing.

[mikekaganski]

I went through “Tools - Options - LibreOffice - Advanced - Open Expert Configuration” without success

Search for UseSystemFileDialog there.

[LibreOfficiant]

So simple

Thanks

[mariosv]

Please, if the answer solves the question click .

[LibreOfficiant]

** I intended to tweak user preferences with a script** - Here’s my take on this particular one:

Option Compatible

Sub Main
	Const USER_PREFERENCE = "Tools - Options - LibreOffice - General - Open/Save Dialogue Boxes - Use LibreOffice dialogue boxes = "
    With GlobalScope.Basiclibraries
	    If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
	' Get user preference, swap it, re-show it and set it back '
	Print USER_PREFERENCE; useProductDialogs : useProductDialogs = Not useProductDialogs
	Print USER_PREFERENCE; useProductDialogs : useProductDialogs = Not useProductDialogs
End Sub

Public Property Get useProductDialogs As Boolean
    ''' Tools - Options - LibreOffice - General - Open/Save Dialogue Boxes - Use LibreOffice dialogue boxes '''
    Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess '
    keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Misc")
    UseProductDialogs = Not keyNode.GetByName("UseSystemFileDialog")
End Property ' <library>.<module>.useProductDialogs '

Public Property Let useProductDialogs(value As Boolean)
    ''' Tools - Options - LibreOffice - General - Open/Save Dialogue Boxes - Use LibreOffice dialogue boxes '''
    Dim keyNode As Object ' com.sun.star.configuration.Configuration(Update)Access '
    keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Misc", True)
    keyNode.setPropertyValue("UseSystemFileDialog", Not value)
    keyNode.commitChanges()
End Property ' <library>.<module>.useProductDialogs '

Use it and abuse it …